# chick.ode 
#
# Model equations for the embryonic chick ventricular cell model in 
# "An ionic model for rhythmic activity in small clusters of embryonic 
# chick ventricular cells", Am J Physiol (Heart Circ Physiol) 2005.
#
# XPPAUT can be downloaded from http://www.math.pitt.edu/~bard/xpp/xpp.html
# Units: V in mV, t in s, rate constants in 1/s, I in pA, capacitance in nF
# Written by T. Krogh-Madsen, 2004


# EQUATIONS
dV/dt = -Itotal(V)/cap
dn/dt = (ninf(V)-n)/taun(V)
ds/dt = (sinf(V)-s)/taus(V)
dd/dt = (dinf(V)-d)/taud(V)
df/dt = (finf(V)-f)/tauf(V)
dk1/dt = (k1inf(V)-k1)/tauk1(V)

# PARAMETERS
param cap=0.0255
param ek1=-81.0,ekr=-81,eks=-75.0,eca=40,eb=40,eseal=0
param gca=30.0,gkr=6.0,gks=7.8,gb=0.2,gk1=3.6,gseal=0.2

# RATE CONSTANTS
alphan(V) = 2.0/3.0*0.08*(V-15.0)/(1-exp(-0.08*(V-15.0)))
betan(V) = 2.0/3.0*0.156*exp(-0.055*(V-15.0))
ninf(V) = alphan(V)/(alphan(V)+betan(V))
taun(V) = 1.0/(alphan(V)+betan(V)) 
alphas(V) = 23.0*exp(0.13*(V+9.0))
betas(V) = 0.036*exp(-0.09*(V+9.0))
sinf(V) = alphas(V)/(alphas(V)+betas(V))
taus(V) = 1.0/(alphas(V)+betas(V)) 
dinf(V) = 1.0/(1.0+exp(-(V+10.0)/6.2))
taud(V) = 0.001*(1.0-exp(-(V+10.0)/6.24))/((1.0+exp(-(V+10.0)/6.24))*(0.035*(V+10.0)))
finf(V) = 1.0/(1.0+exp((V+42.8)/8.4))
tauf(V) = 0.001/(0.0197*exp(-(0.0337*(V+10.0))*(0.0337*(V+10.0)))+0.02)
alphak1(V) = 1000*1.02/(1+exp(0.2385*(V-ek1-59.215)))
betak1(V) = 1000*(0.49124*exp(0.08032*(V-ek1+5.476))+exp(0.06175*(V-ek1-594.31)))/(1.0+exp(-0.5143*(V-ek1+4.753)))
k1inf(V) = alphak1(V)/(alphak1(V)+betak1(V))
tauk1(V) = 1.0/(alphak1(V)+betak1(V)) 

# CURRENTS
IKs(V) = gks*n*(V-eks)
IKr(V) = gkr*s/(1.0+exp((V+100.0)/25.0))*(V-ekr)
ICa(V) = gca*d*f*(V-eca)
Ib(V) = gb*(V-eb)
IK1(V) = gk1*k1*(V-ek1)
Iseal(V) = gseal*(V-eseal)
Itotal(V) = IKs(V)+IKr(V)+ICa(V)+Ib(V)+IK1(V)+Iseal(V)

# INITIAL CONDITIONS
init V=-66.5526,n=0.0764,s=0.8019,d=0.00010932,f=0.6309,k1=0.2953

@TOTAL=4,DT=0.0001,XLO=2,XHI=3.5,YLO=-80,YHI=40,method=gear,maxstor=1000000,TOTAL=4

done